معالِجات EVM المسبقة
توسّع QoreChain محرك QoreChain EVM بـ ستة عقود معالَجة مسبقًا مخصصة تكشف ميزات على مستوى البروتوكول مباشرةً لـ Solidity. توفّر هذه المعالِجات المسبقة وصولًا على السلسلة إلى التشفير ما بعد الكمّي، وتقييم مخاطر الذكاء الاصطناعي، والمراسلة عبر الأجهزة الافتراضية، ومعاملات إجماع PRISM.
المعالِجات المسبقة الست الخاصة بـ QoreChain الواردة أدناه مُضمّنة في العقدة، لكن EVM لا تستدعي إلا العناوين المدرجة في المعامل active_static_precompiles. وعلى الشبكة الرئيسية qorechain-vladi (معرّف سلسلة EVM 9801) تكون هذه القائمة فارغة وقت كتابة هذا النص، لذا لا يوجد أي معالِج مفعّل هناك. وعلى الشبكة الاختبارية qorechain-diana (معرّف سلسلة EVM 9800) تكون PQC Verify وPQC Key Status وPRISM Consensus Params مفعّلة، فعّلها مقترح حوكمة الشبكة الاختبارية 21 (أُقرّ في 27 أكتوبر 2026)، وCrossVM Bridge (0x…0901) ضمن القائمة أيضًا (قُرئت في 7 نوفمبر 2026؛ ويعمل مع قائمة سماح بعقود جرت مراجعتها، راجع حالة الشبكة). أما المعالِجان المسبقان للذكاء الاصطناعي فغير مفعّلين على أي من الشبكتين. ينجح الاستدعاء إلى عنوان غير مدرج في القائمة ويعيد بيانات فارغة (0x)؛ فلا يتراجع ولا يعيد خطأ. راجع حالة الشبكة قبل الاعتماد على أي منها.
حالة الشبكة
| المعالِج المسبق | العنوان | qorechain-vladi (الشبكة الرئيسية) | qorechain-diana (الشبكة الاختبارية) |
|---|---|---|---|
| CrossVM Bridge | 0x…0901 | غير مفعّل | مفعّل مع قائمة سماح (قُرئت القائمة في 7 نوفمبر 2026؛ وبلغ استدعاء eth_call بعد ترقية v3.2.7 عقدًا في قائمة السماح ورُفض لهدف خارج القائمة؛ راجع Multi-VM) |
| PQC Verify | 0x…0A01 | غير مفعّل | مفعّل (منذ 27 أكتوبر 2026) |
| PQC Key Status | 0x…0A02 | غير مفعّل | مفعّل (منذ 27 أكتوبر 2026) |
| AI Risk Score | 0x…0B01 | غير مفعّل | غير مفعّل |
| AI Anomaly Check | 0x…0B02 | غير مفعّل | غير مفعّل |
| PRISM Consensus Params | 0x…0C01 | غير مفعّل | مفعّل (منذ 27 أكتوبر 2026) |
الحالة كما قُرئت من المعامل الحي active_static_precompiles في 27 أكتوبر 2026 (وأُعيدت قراءته على الشبكة الرئيسية في 4 نوفمبر 2026، بعد v3.2.6: ما زالت فارغة؛ وأُعيدت قراءة الشبكتين في 7 نوفمبر 2026: الشبكة الرئيسية فارغة، وشبكة الاختبار تسرد 0x…0901 و0x…0A01 و0x…0A02 و0x…0C01). وهو معامل للسلسلة تغيّره الحوكمة، لذا لا تتغير قائمة كل شبكة إلا عند إقرار مقترح حوكمة؛ وقد ضُبطت قائمة الشبكة الاختبارية بالمقترح 21، ولا يوجد وقت كتابة هذا النص أي مقترح للشبكة الرئيسية يغيّرها. أدخل الإصدار v3.2.3 (الشبكة الرئيسية، 20 أكتوبر 2026) النسختين المُحصَّنتين من CrossVM Bridge ومن معالِج AI Anomaly المسبق في الملف الثنائي خلف ميزة بروتوكول، لكنه لم يفعّل أي معالِج مسبق، ولا يغيّر ذلك لا الإصدار v3.2.4 (الشبكة الرئيسية منذ 23 أكتوبر 2026، والشبكة الاختبارية منذ 19 أكتوبر 2026) ولا الإصدار v3.2.6 (الشبكة الرئيسية منذ 4 نوفمبر 2026) ولا الإصدار v3.2.7 (الشبكة الاختبارية منذ 6 نوفمبر 2026، والشبكة الرئيسية منذ 12 نوفمبر 2026): فقد قُرئت قائمة الشبكة الرئيسية مجددًا في 12 نوفمبر 2026 وما زالت فارغة. وتأتي المعالِجات المسبقة للقراءة فقط الخاصة بـ PQC والإجماع أولًا، ثم زوج الذكاء الاصطناعي بعد جاهزية مساره للقراءة فقط بالفاصلة الثابتة، ثم CrossVM Bridge أخيرًا. يسرد هذا الجدول ما طُبّق فقط: فالمقترح الذي ما زال في فترة التصويت ليس حالة.
تحقّق من القائمة الحالية بنفسك (القائمة الفارغة تعني أنه لا يوجد أي معالِج مفعّل):
curl -s https://api.qore.host/cosmos/evm/vm/v1/params | jq .params.active_static_precompiles
curl -s https://api-testnet.qore.host/cosmos/evm/vm/v1/params | jq .params.active_static_precompiles
الحماية من بيانات الإرجاع الفارغة
لأن العنوان غير المفعّل (أو الذي لا يتبع QoreChain) يعيد نجاحًا دون بيانات، لا تقرأ أبدًا بايتات الإرجاع الخام لاستدعاء منخفض المستوى دون التحقق من طولها. يتراجع كل من abi.decode واستدعاءات الواجهات المنمّطة عند البيانات الفارغة، وهي النتيجة الآمنة؛ أما الاستدعاء منخفض المستوى المكتوب يدويًا فيجب أن يتحقق من ذلك صراحةً:
(bool ok, bytes memory ret) = address(0x0000000000000000000000000000000000000a02)
.staticcall(abi.encodeWithSignature("pqcKeyStatus(address)", account));
require(ok && ret.length >= 96, "precompile not active");
(bool registered, uint8 algorithmId, bytes memory pubkey) = abi.decode(ret, (bool, uint8, bytes));
لا ترسل قيمة إلى هذه العناوين. فهي غير payable، وتبقى القيمة المرسلة إلى عنوان معالِج مسبق غير مفعّل هناك دون أي وسيلة لاستردادها.
على الشبكة الاختبارية، يمكنك التحقق سريعًا من أن المعالِجات المسبقة الثلاثة المفعّلة تستجيب (باستخدام cast من Foundry؛ وعلى الشبكة الرئيسية تعيد هذه العناوين بيانات فارغة بدلًا من ذلك):
RPC=https://evm-testnet.qore.host
cast call 0x0000000000000000000000000000000000000c01 "rlConsensusParams()(uint256,uint256,uint256,uint256)" --rpc-url $RPC
cast call 0x0000000000000000000000000000000000000a02 "pqcKeyStatus(address)(bool,uint8,bytes,bool)" 0x0000000000000000000000000000000000000001 --rpc-url $RPC
المعالِجات المسبقة القياسية
إلى جانب المعالِجات المسبقة الستة الخاصة بـ QoreChain، تحمل العقدة المعالِجات المسبقة القياسية في cosmos/evm. وهي تخضع للقاعدة نفسها: لا تعمل إلا حيث أدرجت الحوكمة عنوانها في active_static_precompiles، ولا يتضمنها بناء المجتمع للعقدة.
| العنوان | المعالِج المسبق |
|---|---|
0x…0100 | P-256 (عديم الحالة) |
0x…0400 | Bech32 (عديم الحالة) |
0x…0800 | Staking |
0x…0801 | Distribution |
0x…0802 | تحويل IBC (ICS-20) |
0x…0804 | Bank (للقراءة فقط) |
0x…0805 | Governance |
0x…0806 | Slashing |
0x…0803 (vesting) محجوز في المصدر الأصلي وغير مُنفَّذ: لا يوجد شيء عند ذلك العنوان. والرهن والتفويض وعمليات المدقّقين على QoreChain تجري على المسار الأصلي فقط (راجع الرهن والمدقّقون)، لذا لا تبنِ تدفقات رهن على المعالِج المسبق Staking. المصدر: docs/EVM_PRECOMPILES.md في مستودع core العام عند الوسم v3.2.6.
خريطة عناوين المعالِجات المسبقة
أرقام الغاز هي ما تحتسبه العقدة بمجرد تفعيل المعالِج المسبق (لكل بايت تعني لكل بايت من مدخلات الاستدعاء).
| المعالِج المسبق | العنوان | الغاز الأساسي | الوصف |
|---|---|---|---|
| CrossVM Bridge | 0x0000000000000000000000000000000000000901 | 50,000 + 4/byte | استدعاءات متزامنة عبر الأجهزة الافتراضية (EVM إلى QoreChain Native) |
| PQC Verify | 0x0000000000000000000000000000000000000a01 | 25,000 + 8/byte | التحقق من توقيعات ML-DSA-87 ما بعد الكمّية |
| PQC Key Status | 0x0000000000000000000000000000000000000a02 | 2,500 | التحقق مما إذا كان للحساب مفتاح PQC مسجّل |
| AI Risk Score | 0x0000000000000000000000000000000000000b01 | 50,000 | الحصول على درجة مخاطر مولّدة بالذكاء الاصطناعي لبيانات المعاملة |
| AI Anomaly Check | 0x0000000000000000000000000000000000000b02 | 40,000 | التحقق مما إذا كان التحويل قد وُسم بأنه شاذ |
| PRISM Consensus Params | 0x0000000000000000000000000000000000000c01 | 1,500 | قراءة معاملات الإجماع الحالية المضبوطة بواسطة PRISM |
واجهات Solidity
IQorePQC.sol
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;
interface IQorePQC {
/// @notice Verify an ML-DSA-87 (Dilithium-5) signature
/// @param pubkey The 2592-byte ML-DSA-87 public key
/// @param signature The 4627-byte ML-DSA-87 signature
/// @param message The original message bytes
/// @return valid True if the signature is valid
function pqcVerify(
bytes calldata pubkey,
bytes calldata signature,
bytes calldata message
) external view returns (bool valid);
/// @notice Check if an account has a registered PQC public key
/// @param account The Ethereum-style address to check
/// @return registered True if a PQC key is registered
/// @return algorithmId The PQC algorithm identifier (1 = ML-DSA-87)
/// @return pubkey The registered public key bytes (empty if not registered)
/// @return possessionProven True only if the key was registered with a verified proof of possession
function pqcKeyStatus(address account)
external
view
returns (bool registered, uint8 algorithmId, bytes memory pubkey, bool possessionProven);
}
من v3.2.4 (الشبكة الرئيسية منذ 23 أكتوبر 2026، والشبكة الاختبارية منذ 19 أكتوبر 2026)، تحمل مخرجات pqcKeyStatus قيمة رابعة هي bool possessionProven بعد pubkey: وهي تبيّن هل جرى إثبات المفتاح الحالي للحساب بإثبات امتلاك جرى التحقق منه (راجع التوقيع ما بعد الكمومي). تُعاد أينما كان المعالِج المسبق مفعّلًا: فهي حية على الشبكة الاختبارية (يعيد الاستدعاء لحساب بلا مفتاح false, 0, 0x, false)، وعلى الشبكة الرئيسية بعد أن تفعّل ترقية هذا المعالِج المسبق. تسرد الواجهة أعلاه المخرجات الأربعة كلها. وعلى العقد الذي يجب أن يثق بالمفتاح أن يتحقق من المخرج الرابع: فإثبات الامتلاك اختياري عند التسجيل، ولذلك لا يكفي registered وحده.
IQoreAI.sol
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;
interface IQoreAI {
/// @notice Get the AI-generated risk score for transaction data
/// @param txData The transaction data to evaluate
/// @return score Risk score in basis points (0-10000)
/// @return level Risk level: 0=SAFE, 1=LOW, 2=MEDIUM, 3=HIGH, 4=CRITICAL
function aiRiskScore(bytes calldata txData)
external
view
returns (uint256 score, uint8 level);
/// @notice Check if a transfer is flagged as anomalous
/// @param sender The sender address
/// @param amount The transfer amount in wei
/// @return anomalyScore The anomaly score (higher = more anomalous)
/// @return flagged True if the transfer exceeds the anomaly threshold
function aiAnomalyCheck(address sender, uint256 amount)
external
view
returns (uint256 anomalyScore, bool flagged);
}
IQoreConsensus.sol
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;
interface IQoreConsensus {
/// @notice Get current PRISM-tuned consensus parameters
/// @return blockTime Current target block time in milliseconds
/// @return baseGasPrice Current base gas price in wei
/// @return validatorSetSize Current active validator set size
/// @return epoch Current PRISM epoch number
function rlConsensusParams()
external
view
returns (
uint256 blockTime,
uint256 baseGasPrice,
uint256 validatorSetSize,
uint256 epoch
);
}
أمثلة الاستخدام
PQC Verify — التحقق من توقيع ما بعد كمّي
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;
import "./interfaces/IQorePQC.sol";
contract PQCVerifier {
IQorePQC constant PQC = IQorePQC(0x0000000000000000000000000000000000000a01);
/// @notice Verify a PQC signature and revert if invalid
function verifyOrRevert(
bytes calldata pubkey,
bytes calldata signature,
bytes calldata message
) external view {
bool valid = PQC.pqcVerify(pubkey, signature, message);
require(valid, "PQC signature verification failed");
}
}
تكلفة الغاز: 25,000 أساسية + 8 غاز لكل بايت من بيانات الإدخال. الإدخال هو الاستدعاء المرمَّز بـ ABI (المفتاح العام 2592 بايت، والتوقيع 4627 بايت، والرسالة، بالإضافة إلى إزاحات ABI والحشو)، لذا تكلّف عملية تحقق ML-DSA-87 النموذجية نحو 85,000-90,000 غاز.
PQC Key Status — التحقق من تسجيل الحساب
contract PQCChecker {
IQorePQC constant PQC_STATUS = IQorePQC(0x0000000000000000000000000000000000000a02);
function requirePQCKey(address account) external view {
(bool registered, , , bool possessionProven) = PQC_STATUS.pqcKeyStatus(account);
require(registered, "Account must have a registered PQC key");
require(possessionProven, "The key was registered without a proof of possession");
}
}
إثبات الامتلاك اختياري عند التسجيل، ولذلك لا يدل registered وحده على أن الحساب يتحكم في المفتاح. وعلى العقد الذي يعتمد على مفتاح مسجَّل لما بعد الكم أن يشترط أيضًا أن تكون قيمة possessionProven صحيحة (true).
تكلفة الغاز: 2,500 ثابتة.
AI Risk Score — تقييم مخاطر المعاملة
import "./interfaces/IQoreAI.sol";
contract RiskGate {
IQoreAI constant AI = IQoreAI(0x0000000000000000000000000000000000000b01);
uint8 constant MAX_ALLOWED_RISK = 2; // Allow up to MEDIUM
function executeIfSafe(bytes calldata txData) external {
(uint256 score, uint8 level) = AI.aiRiskScore(txData);
require(level <= MAX_ALLOWED_RISK, "Risk level too high");
// Proceed with execution...
}
}
مستويات المخاطر:
| المستوى | القيمة |
|---|---|
| SAFE | 0 |
| LOW | 1 |
| MEDIUM | 2 |
| HIGH | 3 |
| CRITICAL | 4 |
يأتي المستوى من تسمية الخطورة التي يحددها محرك الذكاء الاصطناعي للمعاملة؛ وتُعاد الدرجة بنقاط الأساس (0 - 10000). لا يوجد تعيين ثابت من نطاقات الدرجات إلى المستويات، لذا اعتمد في القرار على level بدلًا من عتبات الدرجة.
تكلفة الغاز: 50,000 ثابتة.
AI Anomaly Check — وسم التحويلات المشبوهة
contract AnomalyGuard {
IQoreAI constant AI = IQoreAI(0x0000000000000000000000000000000000000b02);
function safeTransfer(address sender, uint256 amount) external view {
(uint256 anomalyScore, bool flagged) = AI.aiAnomalyCheck(sender, amount);
if (flagged) {
revert("Transfer flagged as anomalous");
}
}
}
تكلفة الغاز: 40,000 ثابتة.
PRISM Consensus Params — قراءة حالة الإجماع
contract ConsensusReader {
IQoreConsensus constant RL = IQoreConsensus(
0x0000000000000000000000000000000000000c01
);
function getBlockTime() external view returns (uint256) {
(uint256 blockTime, , , ) = RL.rlConsensusParams();
return blockTime;
}
function getCurrentEpoch() external view returns (uint256) {
(, , , uint256 epoch) = RL.rlConsensusParams();
return epoch;
}
}
تكلفة الغاز: 1,500 ثابتة، إضافةً إلى قراءات الحالة التي يجريها الاستدعاء بالتكلفة القياسية.
منذ v3.2.6 (تعمل بها الشبكتان أو بإصدار أحدث؛ أما المعالِج المسبق نفسه فهو فعّال على الشبكة الاختبارية فقط) تعيد rlConsensusParams القيم التي تحتفظ بها وحدة rlconsensus بدلًا من القيم الثابتة البديلة: هدف زمن الكتلة المطبَّق بالميلي ثانية، والحد الأدنى المطبَّق لسعر الغاز، والقيمة default_validator_set_size للوحدة، والحقبة الحالية للوكيل. وعلى الشبكة الاختبارية في 27 أكتوبر 2026 أعادت 5000 و100 و100 و1 (وهي القيم المطبَّقة نفسها التي يعيدها GET /qorechain/rlconsensus/v1/applied_params، راجع نقاط REST / gRPC). هذه هي إعدادات الوحدة نفسها، وليست زمن الكتلة المقيس (نحو 3.1 ثانية على الشبكة الرئيسية ونحو 1.3 ثانية على الشبكة الاختبارية)، ويعمل الوكيل في وضع الظل على الشبكة الاختبارية فلا يطبّق شيئًا. وعلى الشبكة الرئيسية ليس العنوان في القائمة الفعّالة: فقد أعاد استدعاء eth_call إليه بيانات فارغة (0x) في 4 نوفمبر 2026، مع أن شيفرة v3.2.6 موجودة في الملف الثنائي (الميزة rl-params-precompile-live مفعّلة). وعلى عقدة أقدم من v3.2.6 يعيد الاستدعاء نفسه قيمًا افتراضية ثابتة بديلة.
CrossVM Bridge — استدعاء QoreChain Native من EVM
المعالِج المسبق CrossVM Bridge غير مفعّل على الشبكة الرئيسية ومفعّل على شبكة الاختبار (قُرئ في 7 نوفمبر 2026)، وقد أُجري عبره استدعاء eth_call للقراءة فقط في 7 نوفمبر 2026 بعد ترقية v3.2.7: فالهدف الموجود في قائمة السماح يصل إلى العقد، والهدف خارجها يُرفض بالرسالة is not allowlisted (التفاصيل في التشغيل البيني بين الأجهزة الافتراضية). وعلى الشبكة الرئيسية يبقى متوقفًا، مع الاستدعاءات عبر الأجهزة الافتراضية، حتى بعد ترقية v3.2.7، إلى أن يصدر قرار حوكمة منفصل. يحمل الملف الثنائي منذ v3.2.3 نسخة مُحصَّنة منه: ترفض STATICCALL؛ وتشغّل الاستدعاء المتداخل على عدّاد غاز محدود بما تبقّى للإطار المستدعي وتسجّله في السجل (journal)، بحيث يؤدي التراجع في العقد المستدعي إلى التراجع أيضًا عن جانب QoreChain Native؛ ولا تصل إلا إلى أهداف QoreChain Native المدرجة في قائمة السماح (تُرفض أهداف EVM)؛ وتحترم قاطع الدائرة (circuit breaker) الخاص بالأجهزة الافتراضية المتقاطعة. وإلى أن يفعّله مقترح حوكمة على الشبكة الرئيسية لا يوجد هناك مسار متزامن من EVM إلى QoreChain Native؛ راجع التشغيل البيني بين الأجهزة الافتراضية لمسار الرسائل MsgCrossVMCall، وهو نفسه معطّل اليوم على الشبكة الرئيسية.
تفك العقدة ترميز calldata على أنها executeCrossVMCall(uint8 targetVM, string targetContract, bytes payload) (محدِّد من 4 بايت، ثم الوسائط المرمَّزة بـ ABI). الاستخدام الوحيد المدعوم هو من EVM إلى QoreChain Native (targetVM = 1)؛ وقد يتغير ABI قبل التفعيل. يرمّز المساعد encodeCrossVmCalldata في @qorechain/rdk هذا التخطيط ابتداءً من 0.6.0 (كانت الإصدارات السابقة ترمّز دالة مختلفة)، ويقرأ المساعد isCrossVmPrecompileActive فيه قائمة active_static_precompiles الحية؛ راجع متعدد الأجهزة الافتراضية.
تكلفة الغاز: 50,000 أساسية + 4 غاز لكل بايت من المدخلات، بالإضافة إلى تكلفة تنفيذ العقد الهدف. راجع التشغيل البيني بين الأجهزة الافتراضية للتفاصيل.
مواقع ملفات الواجهات
ملفات واجهة Solidity متاحة في المستودع للاستيراد المباشر:
contracts/
interfaces/
IQorePQC.sol
IQoreAI.sol
IQoreConsensus.sol
ثبّتها في مشروع Hardhat أو Foundry الخاص بك:
# Copy interfaces to your project
cp -r contracts/interfaces/ my-project/contracts/interfaces/
أو أشِر إليها عبر مسار الاستيراد في ملفات Solidity الخاصة بك:
import "./interfaces/IQorePQC.sol";
import "./interfaces/IQoreAI.sol";
import "./interfaces/IQoreConsensus.sol";
الخطوات التالية
- التشغيل البيني بين الأجهزة الافتراضية — توثيق كامل للمراسلة عبر الأجهزة الافتراضية
- تطوير EVM — نشر عقود Solidity
- تجريد الحساب — مصادِقات المحافظ المرتبطة وقواعد الإنفاق (مفعّلة على الشبكة الاختبارية، ومعطّلة على الشبكة الرئيسية)